home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / AMIGA / AMICUS / AMICUS05.ADF / asm / mylib.asm < prev    next >
Assembly Source File  |  1986-01-15  |  9KB  |  343 lines
  1.  
  2. * mylib.asm AmigaLink 1/30/86
  3. *************************************************************************
  4. *                                            *
  5. *    Copyright (C) 1985, Commodore Amiga Inc.  All rights reserved.   *
  6. *                                            *
  7. ************************************************************************/
  8.  
  9.  
  10. *************************************************************************
  11. *
  12. * mylib.asm -- skeleton library code
  13. *
  14. * Source Control
  15. * ------ -------
  16. * 
  17. * $Header: amain.asm,v 31.3 85/10/18 19:04:04 neil Exp $
  18. *
  19. * $Locker: neil $
  20. *
  21. * $Log:   amain.asm,v $
  22. *
  23. ************************************************************************/
  24.      SECTION   section
  25.  
  26.      NOLIST
  27.      include "exec/types.i"
  28.      include "exec/nodes.i"
  29.      include "exec/lists.i"
  30.      include "exec/libraries.i"
  31.      include "exec/alerts.i"
  32.      include "exec/initializers.i"
  33.      include "exec/resident.i"
  34.      include "libraries/dos.i"
  35.  
  36.      include "asmsupp.i"
  37.  
  38.      include "mylib.i"
  39.  
  40.      LIST
  41.  
  42.      ;------ These don't have to be external, but it helps some
  43.      ;------ debuggers to have them globally visible
  44.      XDEF Init
  45.      XDEF Open
  46.      XDEF Close
  47.      XDEF Expunge
  48.      XDEF Null
  49.      XDEF myName
  50.      XDEF MyFunc0
  51.      XDEF MyFunc1
  52.  
  53.      XREF _AbsExecBase
  54.  
  55.      XLIB OpenLibrary
  56.      XLIB CloseLibrary
  57.      XLIB Alert
  58.      XLIB FreeMem
  59.      XLIB Remove
  60.  
  61.  
  62.  
  63.      ; The first executable location.  This should return an error
  64.      ; in case someone tried to run you as a program (instead of
  65.      ; loading you as a library).
  66. Start:
  67.      CLEAR     d0
  68.      rts
  69.  
  70. ;-----------------------------------------------------------------------
  71. ; A romtag structure.  Both "exec" and "ramlib" look for
  72. ; this structure to discover magic constants about you
  73. ; (such as where to start running you from...).
  74. ;-----------------------------------------------------------------------
  75.  
  76.      ; Most people will not need a priority and should leave it at zero.
  77.      ; the RT_PRI field is used for configuring the roms.  Use "mods" from
  78.      ; wack to look at the other romtags in the system
  79. MYPRI     EQU  0
  80.  
  81. initDDescrip:
  82.                          ;STRUCTURE RT,0
  83.        DC.W    RTC_MATCHWORD       ; UWORD RT_MATCHWORD
  84.        DC.L    initDDescrip        ; APTR  RT_MATCHTAG
  85.        DC.L    EndCode        ; APTR  RT_ENDSKIP
  86.        DC.B    RTF_AUTOINIT        ; UBYTE RT_FLAGS
  87.        DC.B    VERSION        ; UBYTE RT_VERSION
  88.        DC.B    NT_LIBRARY          ; UBYTE RT_TYPE
  89.        DC.B    MYPRI               ; BYTE  RT_PRI
  90.        DC.L    myName         ; APTR  RT_NAME
  91.        DC.L    idString       ; APTR  RT_IDSTRING
  92.        DC.L    Init           ; APTR  RT_INIT
  93.                          ; LABEL RT_SIZE
  94.  
  95.  
  96.      ; this is the name that the library will have
  97. myName:        MYLIBNAME
  98.  
  99.      ; a major version number.
  100. VERSION:  EQU  1
  101.  
  102.      ; A particular revision.  This should uniquely identify the bits in the
  103.      ; library.  I use a script that advances the revision number each time
  104.      ; I recompile.  That way there is never a question of which library
  105.      ; that really is.
  106. REVISION: EQU  17
  107.  
  108.      ; this is an identifier tag to help in supporting the library
  109.      ; format is 'name version.revision (dd MON yyyy)',<cr>,<lf>,<null>
  110. idString: dc.b 'mylib 1.0 (31 Oct 1985)',13,10,0
  111.  
  112. dosName:  DOS`00`00u`A4
  113.  
  114.      ; force word allignment
  115.      ds.w 0
  116.  
  117.  
  118.      ; The romtag specified that we were "RTF_AUTOINIT".  This means
  119.      ; that the RT_INIT structure member points to one of these
  120.      ; tables below.  If the AUTOINIT bit was not set then RT_INIT
  121.      ; would point to a routine to run.
  122.  
  123. Init:
  124.      DC.L MyLib_Sizeof        ; data space size
  125.      DC.L funcTable      ; pointer to function initializers
  126.      DC.L dataTable      ; pointer to data initializers
  127.      DC.L initRoutine         ; routine to run
  128.  
  129.  
  130. funcTable:
  131.  
  132.      ;------ standard system routines
  133.      dc.l Open
  134.      dc.l Close
  135.      dc.l Expunge
  136.      dc.l Null
  137.  
  138.      ;------ my libraries definitions
  139.      dc.l MyFunc0
  140.      dc.l MyFunc1
  141.  
  142.      ;------ function table end marker
  143.      dc.l -1
  144.  
  145.  
  146.      ; The data table initializes static data structures.
  147.      ; The format is specified in exec/InitStruct routine's
  148.      ; manual pages.  The INITBYTE/INITWORD/INITLONG routines
  149.      ; are in the file "exec/initializers.i".  The first argument
  150.      ; is the offset from the library base for this byte/word/long.
  151.      ; The second argument is the value to put in that cell.
  152.      ; The table is null terminated
  153. dataTable:
  154.      INITBYTE  LH_TYPE,NT_LIBRARY
  155.      INITLONG  LN_NAME,myName
  156.      INITBYTE  LIB_FLAGS,LIBF_SUMUSED!LIBF_CHANGED
  157.      INITWORD  LIB_VERSION,VERSION
  158.      INITWORD  LIB_REVISION,REVISION
  159.      INITLONG  LIB_IDSTRING,idString
  160.      DC.L 0
  161.  
  162.  
  163.      ; This routine gets called after the library has been allocated.
  164.      ; The library pointer is in D0.  The segment list is in A0.
  165.      ; If it returns non-zero then the library will be linked into
  166.      ; the library list.
  167. initRoutine:
  168.  
  169.      ;------ get the library pointer into a convenient A register
  170.      move.l    a5,-(sp)
  171.      move.l    d0,a5
  172.  
  173.      ;------ save a pointer to exec
  174.      move.l    a6,ml_SysLib(a5)
  175.  
  176.      ;------ save a pointer to our loaded code
  177.      move.l    a0,ml_SegList(a5)
  178.  
  179.      ;------ open the dos library
  180.      lea  dosName(pc),a1
  181.      CLEAR     d0
  182.      CALLSYS   OpenLibrary
  183.  
  184.      move.l    d0,ml_DosLib(a5)
  185.      bne.s     1$
  186.  
  187.      ;------ can't open the dos!  what gives
  188.      ALERT     AG_OpenLib!AO_DOSLib
  189.  
  190. 1$:
  191.      ;------ now build the static data that we need
  192.  
  193.      ;
  194.      ; put your initialization here...
  195.      ;
  196.  
  197.      move.l    a5,d0
  198.      move.l    (sp)+,a5
  199.      rts
  200.  
  201. ;----------------------------------------------------------------------
  202. ;
  203. ; here begins the system interface commands.  When the user calls
  204. ; OpenLibrary/CloseLibrary/RemoveLibrary, this eventually gets translated
  205. ; into a call to the following routines (Open/Close/Expunge).  Exec
  206. ; has already put our library pointer in A6 for us.  Exec has turned
  207. ; off task switching while in these routines (via Forbid/Permit), so
  208. ; we should not take too long in them.
  209. ;
  210. ;----------------------------------------------------------------------
  211.  
  212.  
  213.      ; Open returns the library pointer in d0 if the open
  214.      ; was successful.  If the open failed then null is returned.
  215.      ; It might fail if we allocated memory on each open, or
  216.      ; if only open application could have the library open
  217.      ; at a time...
  218.  
  219. Open:          ; ( libptr:a6, version:d0 )
  220.  
  221.      ;------ mark us as having another opener
  222.      addq.w    #1,LIB_OPENCNT(a6)
  223.  
  224.      ;------ prevent delayed expunges
  225.      bclr #LIBB_DELEXP,ml_Flags(a6)
  226.  
  227.      move.l    a6,d0
  228.      rts
  229.  
  230.      ; There are two different things that might be returned from
  231.      ; the Close routine.  If the library is no longer open and
  232.      ; there is a delayed expunge then Close should return the
  233.      ; segment list (as given to Init).  Otherwise close should
  234.      ; return NULL.
  235.  
  236. Close:         ; ( libptr:a6 )
  237.     
  238.      ;------ set the return value
  239.      CLEAR     d0
  240.  
  241.      ;------ mark us as having one fewer openers
  242.      subq.w    #1,LIB_OPENCNT(a6)
  243.  
  244.      ;------ see if there is anyone left with us open
  245.      bne.s     1$
  246.  
  247.      ;------ see if we have a delayed expunge pending
  248.      btst #LIBB_DELEXP,ml_Flags(a6)
  249.      beq.s     1$
  250.  
  251.      ;------ do the expunge
  252.      bsr  Expunge
  253. 1$:
  254.      rts
  255.  
  256.  
  257.      ; There are two different things that might be returned from
  258.      ; the Expunge routine.  If the library is no longer open
  259.      ; then Expunge should return the segment list (as given to
  260.      ; Init).  Otherwise Expunge should set the delayed expunge
  261.      ; flag and return NULL.
  262.      ;
  263.      ; One other important note: because Expunge is called from
  264.      ; the memory allocator, it may NEVER Wait() or otherwise
  265.      ; take long time to complete.
  266.  
  267. Expunge:  ; ( libptr: a6 )
  268.  
  269.      movem.l   d2/a5/a6,-(sp)
  270.      move.l    a6,a5
  271.      move.l    ml_SysLib(a5),a6
  272.      
  273.      ;------ see if anyone has us open
  274.      tst.w     LIB_OPENCNT(a5)
  275.      beq  1$
  276.  
  277.      ;------ it is still open.  set the delayed expunge flag
  278.      bset #LIBB_DELEXP,ml_Flags(a5)
  279.      CLEAR     d0
  280.      bra.s     Expunge_End
  281.  
  282. 1$:
  283.      ;------ go ahead and get rid of us.  Store our seglist in d2
  284.      move.l    ml_SegList(a5),d2
  285.  
  286.      ;------ unlink from library list
  287.      move.l    a5,a0
  288.      CALLSYS   Remove
  289.      
  290.      ;
  291.      ; device specific closings here...
  292.      ;
  293.  
  294.      ;------ close the dos library
  295.      move.l    ml_DosLib(a5),a1
  296.      CALLSYS   CloseLibrary
  297.  
  298.      ;------ free our memory
  299.      move.l    a5,a1
  300.      move.l    LIB_NEGSIZE(a5),d0
  301.  
  302.      sub.l     d0,a1
  303.      add.l     LIB_POSSIZE(a5),d0
  304.  
  305.      CALLSYS   FreeMem
  306.  
  307.      ;------ set up our return value
  308.      move.l    d2,d0
  309.  
  310. Expunge_End:
  311.      movem.l   (sp)+,d2/a5/a6
  312.      rts
  313.  
  314.  
  315. Null:
  316.      CLEAR     d0
  317.      rts
  318.  
  319. ;----------------------------------------------------------------------
  320. ;
  321. ; here begins the library specific commands
  322. ;
  323. ;----------------------------------------------------------------------
  324.  
  325. MyFunc0:
  326.      CLEAR     d0
  327.      rts
  328.  
  329. MyFunc1:
  330.      moveq     #1,d0
  331.      rts
  332.  
  333.  
  334.      ; EndCode is a marker that show the end of your code.
  335.      ; Make sure it does not span sections nor is before the
  336.      ; rom tag in memory!  It is ok to put it right after
  337.      ; the rom tag -- that way you are always safe.  I put
  338.      ; it here because it happens to be the "right" thing
  339.      ; to do, and I know that it is safe in this case.
  340. EndCode:
  341.  
  342.      END
  343.